Whenever the abbreviations src or dst are used in the assembly language syntax description for an instruction, it means that only the accumulators A and B may be used for that particular operand. These are seen everywhere, but two classic examples are ld, which always loads data into an accumulator from somewhere else, and sth/stl, which always store data from an accumulator to somewhere else.

Examples:

        
	ld     *AR5,A     ; sets A = (contents of memory location pointed to by AR5)
	sth    B,*AR7+    ; sets (contents of memory location pointed to be AR7) = B,
	;    and then increments AR7 by one
	
      

Many of the TMS320C54x registers are memory-mapped, meaning that they occupy real addresses at the low end of data memory space. The most commonly used of these are the auxiliary registers AR0 through AR7. Whenever the abbreviation MMR is used in the assembly language syntax description for an instruction, it means that any memory-mapped register may be used for that particular operand. Only eight instructions use memory-mapped register addressing: ldm, mvdm, mvmd, mvmm, popm, pshm, stlm, and stm. With mvmm, since the instruction accepts two memory-mapped register operands, MMRx and MMRy, only AR0-AR7 and SP may be used.

Do not use an asterisk in front of ARx variables here, since this is not indirect addressing.

Examples:

        
	mvmm    AR3,AR5   ; sets AR5 = AR3
	stm     #5,AR2    ; sets AR2 = 5
	ldm     AR0,A     ; sets A = AR0
	
      

Immediate addressing means that the numerical value of the data is itself provided within the assembly instruction. Various TMS320C54x instructions allow immediate data of 3, 5, 8, 9, or 16 bits in length, which are signified in the assembly language syntax descriptions with one of the above symbols. The 16-bit form is the most common and is signified by #lk. 16-bit immediate values always require an extra instruction word and therefore take an extra machine cycle to execute.

An immediate data operand is almost always specified in assembler syntax by prepending a pound sign (#) to the data. Depending on the context, the assembler may assume that you meant immediate addressing anyway.

Examples:

        
	ld       #0,A      ; sets A = 0
	cmpm     AR1,#1    ; sets flag TC = 1 if AR1 == 1; else TC = 0
	
      

Labels make this more complicated. Recall that a label in your assembly code is nothing more than shorthand for the memory address where the labeled code or data is stored. So does an instruction like

        
	stm     coef,AR2   ; sets AR2 = memory address of label coef
        
      

mean to store the contents of memory location coef in AR2, or does it mean to store the memory address coef itself in AR2? The second interpretation is correct. Because the stm instruction has only one form, expecting a #lk immediate operand, the assembler does not care whether the label is prefixed with a pound sign or not. Still, it would have been better for us to include the pound sign in the above example for clarity.

Many instructions have several versions allowing the use of different addressing modes (see ld for a good example of this). With these instructions, including the pound sign is not optional when specifying immediate addressing. The only safe rule, then, is always to prefix the label with a pound sign if you wish to specify the memory address of the label and not the contents of that address.

If you are not sure how a particular instruction has been assembled, you can always examine the .lst file produced by the assembler, and compare the hexadecimal opcodes listed to the left of the assembly instructions with the assembly opcodes given in the assembly language manual (Chapter 4 of the Mnemonic Instruction Set [link] reference).

In the modes called direct addressing by TI, the instruction opcode contains a memory offset (see the "dma" bits on page 5-8 of the CPU and Peripherals [link] reference) seven bits long, which is combined with either the DP (data pointer) or SP (stack pointer) register to obtain a complete 16-bit data-memory address. This divides the data memory into pages of 128 words each.

SP is initialized for you in the core file and should not need to be modified. SP-referenced direct addressing is used by the pshd, pshm, popd, and popm instructions for stack manipulation, as well as by all subroutine calls and returns, which save program addresses on the stack.

DP-referenced direct addressing is available wherever you see the Smem abbreviation in an assembly syntax description. The advantage of DP-referenced addressing over the *(lk) form described in the next section is that DP-referenced addressing will not add an extra instruction word (and corresponding extra machine cycle). The disadvantage is that it is limited to 128 words of contiguous memory, and you have to make sure that DP points to the right 128 words. DP may be changed with the ld instruction as needed.

Examples:

        
	ld     10,A      ; sets A = (contents of memory location DP + 10)
	add    6,B       ; sets B = B + (contents of memory location DP + 6)
        
      

This seems to be TI's term for all the forms of direct addressing which it does not call direct addressing! It is represented in assembly-instruction syntax-definitions using one of the above abbreviations (*(lk) addressing is available when the syntax definition says Smem).

          
	  f3ptr   .word    0          ; reserve one word of storage; initialize to 0
	  . . . .  
	  mvdm    f3ptr,AR4  ; set AR4 = memory address of f3ptr
          
        

          
	  firs    *AR3+,*AR4+,coefs
          
        

          
	  hold    .word    1           ; reserve one word of storage and initialize to 1
	  count   .word    0           ; reserve one word of storage and initialize to 0
	  . . . .
	  ld       *(count),B  ; sets B = 0 (assuming memory was not changed)
	  st       T,*(hold)   ; sets (storage location at address hold) = T
          
        

Indirect addressing on the TMS320C54x always uses the auxiliary registers AR0 through AR7 and comes in two basic flavors. These are easily recognized from the assembly language syntax descriptions as either Smem or Xmem/Ymem.

          
	  stl    B,*AR6     ; sets (contents of location pointed to by AR6) = low word of B
	  stl    B,*AR6+0%  ; sets (contents of location pointed to by AR6) = low word of B,
	  ;      then increments AR6 with circular addressing
	  mar    *+AR3(-6)  ; decrements AR3 by 6 (increment by -6)
          
        

The ld instruction is illustrative of the many possible addressing modes which can be selected with the proper choice of assembly language syntax:

        
	ld      #0,A         ; immediate data:  sets A = 0
	ld      0,A          ; DP-referenced direct:  sets A = (contents of the address DP + 0)
	ld      mydata,A     ; DP-referenced direct:  sets A = (contents of the address
	;       DP + lower seven bits of mydata)
	ld      #mydata,A    ; immediate data:  sets A = 16 bit address mydata
	ld      *(mydata),A  ; *(lk) direct:  sets A = (contents of the 16 bit address mydata)
	ld      B,A          ; accumulator:  sets A = B
	ld      *AR1+,A      ; indirect:  sets A = (contents of address pointed to by AR1),
	;       and afterwards increments AR1 by one
	ldm     AR2,A        ; memory-mapped register:  sets A = AR2