Bước 3: Hàm PaintPicture cho phép ta copy rất nhanh một khối dữ liệu đồ họa, nói nôm na là một khu vực trong một hình đồ họa trên form, PictureBox đến một nơi khác. Thí dụ ta copy một hình từ chỗ nầy đến chỗ khác trong form, hay từ form/PictureBox ra đối tượng Printer để sau đó ta in nó ra.

Ta nhấp đúp lên PictureBox Icon trong ToolBox để đặt một PictureBox lên form với các thuộc tính sau:

Name: picDohoa.

Visible: False (để ta không thấy nó lúc chạy chương trình).

Bước 4: Bây giờ ta load một hình vào thuộc tính Picture của picDohoa bằng cách chọn một tập tin hình ảnh từ cửa sổ Properties. Ở đây ta chọn INTL_NO.BMP từ folder \Program Files\Microsoft Visual Studio\Common\Graphics\Bitmaps\Assorted

Hình 7

Hình 8

Hình II.3: Lựa chọn tập tin ảnh

Trong chương trình nầy ta muốn hễ khi đè nút trái của Mouse xuống và di chuyển chuột thì khi con trỏ chuột đi đến đâu, hình INTL_NO được vẽ đến đó.

Bước 5: Ta sẽ dùng một biến để đánh dấu nút-trái-của-Mouse-Down, đặt tên là IsMousedown. Khi nhận được sự kiện MouseDown ta đặt IsMouseDown thành True, và khi nhận được sự kiện MouseUp ta đặt lại IsMouseDown thành False. Mỗi lần nhận được sự kiện MouseMove thì nếu IsMouseDown là True ta sẽ vẽ hình INTL_NO.

Trong phần [General]\[Declaration], khai báo biến sau:

Dim IsMouseDown As Boolean

Bước 6: Đầu tiên biến này phải được khởi tạo là False trong sự kiện Form_Load:

Private Sub Form_Load()

IsMouseDown = False

End Sub

Bước 7: Ta xử lý các sự kiện MouseUp, MouseDown, MouseMove của Form như sau:

Private Sub Form_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)

IsMouseDown = True

End Sub

Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)

If IsMouseDown Then

' Vẽ hình tại vị trí X, Y

PaintPicture picDohoa.Picture, X, Y, picDohoa.Width, picDohoa.Height

End If

End Sub

Private Sub Form_MouseUp(Button As Integer, Shift As Integer, X As Single, Y As Single)

IsMouseDown = False

End Sub

Bước 8: Chọn Form1 trong cửa sổ Project Explorer, ta sẽ xử lý sự kiện khi ta nhấp chọn mục Xoa man hinh trên menu như sau:

Private Sub mnuXoa_Click()

Cls

End Sub

Bước 9: Khi ta nhấp chọn mục Thoat trên menu, chương trình tự động đóng lại ⇒⇒ size 12{ drarrow } {} sự kiện mnuThoat_Click được xử lý:

Private Sub mnuThoat_Click()

End

End Sub

Bước 10: Lưu dự án lại, chạy chương trình, thử kéo chuột trên Form. Quan sát kết quả.

HÀM PSET

Bước 11: Ta dùng hàm PSet (Point Set) để vẽ một pixel lên form. Ta cần cho biết PSet ở đâu và với màu gì, tức là ta cho nó tọa độ X,Y của pixel và một màu được tính từ hàm RGB.

Dưới đây là đoạn mã để vẽ pixels đủ màu lên form một cách bất chừng (randomly) về vị trí và màu sắc khi người dùng chọn mục Pixel trên menu:

Private Sub mnuPixel_Click()

Dim i As Integer

' Tọa độ vẽ (X, Y)

Dim iXCoord As Integer

Dim iYCoord As Integer

' Màu cơ bản

Dim iRed As Integer

Dim iGreen As Integer

Dim iBlue As Integer

' Sinh các số ngẫu nhiên

Randomize

' Vẽ 2000 điểm ngẫu nhiên

For i = 1 To 2000

' Lấy tọa độ X (ngẫu nhiên)

' Note that Rnd(1) returns a real number between 0 and 1, eg: 0.384

iXCoord = Int(Rnd(1) * ScaleWidth)

' Lấy tọa độ Y (ngẫu nhiên)

iYCoord = Int(Rnd(1) * ScaleHeight)

' Lấy giá trị ngẫu nhiên từ 0 – 254 cho mỗi màu cơ bản

iRed = Int(Rnd(1) * 255)

iGreen = Int(Rnd(1) * 255)

iBlue = Int(Rnd(1) * 255)

' Vẽ 1 pixel tại tọa độ iXCoord, iYCoord

PSet (iXCoord, iYCoord), RGB(iRed, iGreen, iBlue)

Next

MsgBox ("Ve xong!")

End Sub

Trong thí dụ trên ta dùng hàm Randomize để sinh sẵn trong bộ nhớ các số thực bất chừng từ 0 đến 0.999. Sau đó mỗi lần ta gọi hàm Rnd(1) là nó sẽ trả về một số thực bất kỳ từ bộ số do hàm Randomize sinh ra. Do đó, Rnd(1) * ScaleWidth sẽ cho ta một số thực có trị số từ 0 đến ScaleWidth. Muốn đổi số thực đó ra số nguyên, ta dùng hàm Int.

Bước 12: Lưu dự án lại, chạy chương trình. Nhấp chọn Pixel trên menu.

Hàm Line vẽ một đường thẳng từ một tọa độ nầy đến một tọa độ khác trong màu do ta chỉ định. Với hai hàm PSet và Line ta có thể làm được rất nhiều chuyện. Thí dụ muốn cho một vật di động, ta xóa vật ấy bằng cách vẽ lại nó với cùng màu của BackColor của form, rồi vẽ vật ấy ở vị trí mới. Muốn vẽ một đa giác như tam giác hay chữ nhật ta ráp nhiều đường thẳng lại với nhau, đầu của mỗi đường thẳng là cuối của đường thẳng vừa mới được vẽ trước. Muốn vẽ hình dạng bên trong một hình chữ nhật ta dùng PSet…

Có ba cách để chỉ định tọa độ của hai đầu của một đường thẳng ta muốn vẽ:

Line (3000,4000)-(3600,4500), vbMagenta

Line (4000,5100)-(4800,4600), vbGreen

Bước 14: Vẽ tam giác với màu đỏ cùng tọa độ trên. Sự kiện mnuTgDo_Click:

Private Sub mnuTgDo_Click()

' Vẽ tam giác màu đỏ

Line (700, 500)-(2800, 2400), vbRed

Line -(1800, 900), vbRed

Line -(700, 500), vbRed

End Sub

Bước 15: Ta có thể vẽ một hình chữ nhật với 4 góc tròn như sau:

Chọn Tools\Add Procedure… để thêm một thủ tục vào:

Name: HcnTron

Type: Sub

Scope: Private

Private Sub HcnTron(ByVal X1 As Integer, ByVal Y1 As Integer, _

ByVal X2 As Integer, ByVal Y2 As Integer)

Const Delta = 50

' Vẽ hcn với 4 góc tròn

Line (X1 + Delta, Y1)-(X2 - Delta, Y1)

Line -Step(Delta, Delta)

Line -(X2, Y2 - Delta)

Line -Step(-Delta, Delta)

Line -(X1 + Delta, Y2)

Line -Step(-Delta, -Delta)

Line -(X1, Y1 + Delta)

Line -Step(Delta, -Delta)

End Sub

Bước 16: Ta cũng có thể tạo bóng bên trong hình chữ nhật bằng cách dùng hàm PSet để chấm các đốm cách nhau chừng 50 pixels như sau:

Private Sub TaoBong(ByVal X1 As Integer, ByVal Y1 As Integer, _

ByVal X2 As Integer, ByVal Y2 As Integer)

Const Delta = 50

Dim i As Integer

Dim j As Integer

' Kiem tra X1 < X2 ?

' Đổi giá trị X1, X2 nếu X1 > X2

If X2 < X1 Then

Temp = X1

X1 = X2

X2 = Temp

End If

' Kiểm tra Y1 < Y2

' Đổi giá trị Y1, Y2 nếu Y1 > Y2

If Y2 < Y1 Then

Temp = Y1

Y1 = Y2

Y2 = Temp

End If

' Vẽ các chấm trong hcn, mỗi chấm cách nhau 50 pixel

For i = X1 + Delta To X2 - Delta Step 50

For j = Y1 + Delta To Y2 - Delta Step 50

PSet (i, j)

Next

Next

End Sub

Bước 17: Bây giờ phối hợp cách vẽ hình chữ nhật với thủ tục TaoBong nói trên và hàm Print ta có thể viết chữ bên trong một khung màu nhạt khi ta xử lý sự kiện mnuHcn_Click:

Private Sub mnuHV_Click()

Dim X1 As Integer

Dim Y1 As Integer

Dim X2 As Integer

Dim Y2 As Integer

' Khởi tạo tọa độ đầu

X1 = 4200: Y1 = 1000

X2 = 6200: Y2 = 2000

' Vẽ hcn

HcnTron X1, Y1, X2, Y2

' Tạo bóng

TaoBong X1, Y1, X2, Y2

' Vị trí để xuất chữ lên màn hình

CurrentX = X1 + 50

CurrentY = Y1 + 50

' Kích thước chữ

Font.Size = 18

' Hiển thị ra màn hình

Print "Xin chao!"

End Sub

Bước 18: Dùng hàm Circle để vẽ hình tròn, hình bầu dục và cung tròn, với bên trong không màu hay được phủ bằng một màu ta chỉ định. Để vẽ, ta phải cho biết tọa độ của tâm của đường tròn và bán kính của nó.

Ta xử lý cho sự kiện mnuTron_Click như sau:

Private Sub mnuTron_Click()

' Vẽ đường tròn tâm 2000,1500 bán kính 800

Circle (2000, 1500), 800

' Vẽ đường thẳng ngang từ tâm

Line (2000, 1500)-Step(0, 800)

' Vẽ đường thẳng đứng từ tâm

Line (2000, 1500)-Step(800, 0)

End Sub

Bước 19: Bây giờ, thay vì vẽ nguyên một đường tròn, ta sẽ chỉ vẽ một cung tròn với màu đỏ. Để chỉ định rằng ta sẽ vẽ từ vị trí nào trên đường tròn đến vị trí nào khác, thí dụ từ 45 độ đến 230 độ, ta cần phải đổi độ ra đơn vị Radian bằng cách dùng hàm Rads như sau:

Chọn Tools\Add Procedure… để thêm một hàm tên Rads với các giá trị sau:

Name: Rads

Type: Function

Scope: Private

Private Function Rads(ByVal Degree As Single) As Single

' Đổi độ sang Radian

Const PI = 22 / 7

Rads = Degree / 180 * PI

End Function

Bước 20: Cung tròn luôn luôn được vẽ ngược chiều kim đồng hồ. Dưới đây là đoạn mã của sự kiện mnuCung_Click để vẽ một cung tròn màu đỏ bán kính 800, tâm (4000, 2000), từ 45 độ đến 230 độ:

Private Sub mnuCung_Click()

Circle (4000, 2000), 800, vbRed, Rads(45), Rads(230)

End Sub

Bước 21: Ta có thể cho tô màu bên trong các hình tròn, hay Pie Slice (một phần của hình tròn) bằng cách đặt thuộc tính FillStyle bằng 0 và chỉ định màu FillColor. Một Pie Slice là một vòng cung đóng kính bởi hai đường thẳng bán kính ở hai đầu. Muốn vẽ một Pie Slice ta đánh thêm dấu trừ ("-") trước hai trị số Radian, tức là dùng -Rads(45), -Rads(230) thay vì Rads(45), Rads(230).

Dưới đây là mã lệnh vẽ hai Pie Slices, có tâm lệch nhau một chút, đồng thời thêm chú thích 87.5% và 12.5%. Hình vẽ này tương tự như các biểu đồ dân số, diện tích… Sự kiện mnuBieudo_Click:

Private Sub mnuBieudo_Click()

FillStyle = 0 ' Cho phép tô màu

FillColor = vbYellow

' Vẽ một Pie Slice từ 90 độ đến 45 độ màu vàng

Circle (3000, 4000), 800, , -Rads(90), -Rads(45)

' Vị trí hiển thị văn bản

CurrentX = 2800: CurrentY = 4400

Print "87.5%"

FillColor = vbBlue

' Vẽ một Pie Slice từ 45 độ đến 90 độ màu xanh

Circle (3050, 3900), 800, , -Rads(45), -Rads(90)

' Vị trí hiển thị văn bản

CurrentX = 3400: CurrentY = 3000

Print "12.5%"

FillStyle = 1 ' Không cho phép tô màu

End Sub

Bước 22: Hàm Circle còn được dùng để vẽ các hình bầu dục (Elip). Vẽ hình bầu dục giống như vẽ một hình tròn nhưng ta cần cho thêm một tham số gọi là Aspect. Aspect là sự liên hệ giữa bán kính ngang (chiều ngang) và bán kính dọc (chiều cao). Thí dụ nếu Aspect=2 thì chiều cao của hình bầu dục gấp đôi chiều ngang, ngược lại, nếu Aspect=0.5 thì chiều ngang sẽ gấp đôi chiều cao.

Dưới đây là đoạn mã ta dùng để vẽ hai hình bầu dục cùng kích thước, một nằm thẳng đứng và một nằm ngang ⇒⇒ size 12{ drarrow } {} Sự kiện mnuBauduc_Click được xử lý:

Private Sub mnuBauduc_Click()

Circle (1400, 3000), 800, vbMagenta, , , 2

Circle (1400, 3000), 800, vbBlue, , , 0.5

End Sub

Bước 23: Lưu dự án và chạy chương trình.

Hình II.4: Sử dụng Common Dialog

Hình 9

MÔ TẢ

Hình 10

Hình II.5

Người chơi phải tiến hành sắp lại các ô số này theo thứ tự để được kết quả như hình II.6 thì trò chơi kết thúc. Chương trình hiển thị câu chúc mừng: “Chuc mung! Ban da thanh cong!!!” & tổng thời gian chơi.

Hình 11

Hình 12

Người chơi có thể thực hiện chơi lại bằng cách chọn File\New. Chương trình sẽ tự động xáo lại các ô chứa số & ô trống theo thứ tự ngẫu nhiên.

Việc sắp xếp lại các ô số được thực hiện bằng cách sử dụng ô trống. Người dùng có thể chuyển một số từ các ô lân cận đến ô trống bằng cách nhấp chuột lên ô số đó. Chẳng hạn trên hình 1 người dùng có thể nhấp ô chứa số 2 để chuyển nó đến ô trống bên dưới & khi đó ô chứa số 2 cũ sẽ thành ô trống mới.

Chú ý rằng người dùng chỉ có thể di chuyển các số thuộc những ô lân cận trống. Chẳng hạn các ô lân cận trống trong hình 1 là những ô 2, 4, 11, 15.

Hình II.7 là một ví dụ khác về các ô lân cận trống. Trong trường hợp này đó là các ô chứa số 9, 2 & 12. Để ý rằng hai ô chứa số 3 & 1 không được xem là ô lân cận.

Hình 13

Hình II.7

CÁC THUẬT TOÁN XỬ LÝ

Xác định một ô có phải là ô lân cận của ô trống hiện hành hay không?

Đánh số thứ tự các ô từ 0 đến 15 theo thứ tự từ phải qua trái & từ trên xuống dưới.

Xác định các lân cận cho từng ô.

Để ý rằng các ô có thứ tự 0 (hàng 1 cột 1), 3 (hàng 1 cột 4), 12 (hàng 4 cột 1) & 15 (hàng 4 cột 4) có số lân cận là 2.

8 ô có thứ tự 1 (hàng 1 cột 2), 2 (hàng 1 cột 3), 4 (hàng 2 cột 1), 7 (hàng 2 cột 4), 8 (hàng 3 cột 1), 11 (hàng 3 cột 4), 13 (hàng 4 cột 1), 14 (hàng 4 cột 3) có số ô lân cận là 3.

4 ô còn lại có thứ tự 5, 6, 9, 10 có số ô lân cận là 4.

Ví dụ: Trong hình 3:

Ô có thứ tự 6 (chứa số 2), có số ô lân cận là 4, đó là các ô có thứ tự 2 (chứa số 3), 5 (không chứa số), 7 (chứa số 15), 10 (chứa số 1).

Ô có thứ tự 16 (chứa số 7), có số ô lân cận là 2, đó là các ô có thứ tự 12 (chứa số 14), 15 (chứa số 13).

Ta có nhận xét rằng, có tất cả 16 ô mỗi ô có tối đa 4 ô lân cận. Như vậy ta có thể sử dụng một mảng 2 chiều để lưu trữ giá trị các ô lân cận.

Dim Neibors(0 To 15, 0 To 3) As Integer

Ví dụ: Ô có thứ tự 0:

Neibors(0,1) = 1 ‘ Lân cận thứ 1 của ô 0 là ô thứ 1

Neibors(0,2) = 4 ‘ Lân cận thứ 2 của ô 0 là ô thứ 4

Neibors(0,3) = -1 ‘ Không có lân cận 3

Neibors(0,4) = -1 ‘ Không có lân cận 4

Nếu một trong các ô lân cận của “ô được Click” có giá trị trống (ô trống) thì hoán đổi nội dung “ô được Click” với ô trống, ngược lại không làm gì cả.

Thuật toán xáo số

Sử dụng thủ tục Randomize & hàm Rnd, thử nghĩ xem cách thức để kiểm tra xem một số đã được sử dụng rồi hay chưa? Viết một chương trình con xáo số riêng.

Di chuyển số đến ô trống

Thực chất là hoán vị nội dung “ô được Click” & “ô trống”.

Kiểm tra trò chơi kết thúc

Trò chơi khi đạt đến trạng thái hình 2 là kết thúc. Viết hàm kiểm tra.

Đếm thời gian chương trình thực thi

Sử dụng bộ định thời gian để đếm thời gian thực thi của chương trình.