ADO sử dụng OLEDB như là trình cung cấp dữ liệu cơ sở. Trình cung cấp OLE DB cho phép người lập trình có thể truy xuất dữ liệu từ cả hai nguồn: quan hệ và phi quan hệ. VB6.0 đã hỗ trợ các trình cung cấp cục bộ cho SQL Server, Oracle và Microsoft Jet/Access.
 |
Ta chỉ cần lập trình với phần giao diện người sử dụng ở phía Client. Việc truy cập cơ sở dữ liệu trên trình duyệt Web hay ứng dụng VB được thực hiện nhờ ADO. Cấu trúc này cho phép ta lập trình một cách nhất quán trên Web cũng như trên ứng dụng.
 |
Mô hình ADO
Mô hình ADO được trình bày theo dạng phân cấp (tương tự DAO và RDO).
Để có thể lập trình với thư viện ADO, ta phải tham chiếu đến thư viện này bằng cách chọn Project\References…\Microsoft ActiveX Data Object 2.0.
Mô hình ADO có 3 đối tượng cốt lõi:
- Connection: kết nối CSDL thật sự.
- Command: thực thi các câu truy vấn dựa vào kết nối dữ liệu.
- RecordSet: là tập các mẩu tin được chọn từ câu truy vấn thông qua đối tượng Command.
Các đối tượng trong mô hình ADO
Đối tượng Connection
Dùng phương thức Open của đối tượng Connection để thiết lập kết nối với nguồn dữ liệu. Để thực hiện điều này ta cần phải thông báo với ADO thông tin kết nối với dạng chuỗi theo kiểu chuỗi kết nối của ODBC. Thuộc tính ConnectionString thực hiện điều này. Ngoài ra ta còn có thể chọn trình cung cấp bằng cách quy định giá trị của thuộc tính Provider của đối tượng.
Để nối kết với dữ liệu, ta cần xác định trình cung cấp OLE DB và chuỗi kết nối. Nếu không xác định được hai yếu tố này, ta sẽ sử dụng trình cung cấp mặc định là ODBC: MSDASQL.
Một số trình cung cấp có sẵn:
- Microsoft OLEDB cho các trình điều khiển ODBC.
- Microsoft OLEDB cho Oracle.
- Microsoft Jet 3.51 OLEDB (Access).
- Microsoft Jet 4.0 OLEDB (Access)
- Microsoft OLEDB cho SQL Server.
- Microsoft OLEDB cho các dịch vụ thư mục.
Ví dụ:
Đối với trình cung cấp ODBC, thuộc tính ConnectionString có thể là một DSN hay là một kết nối không có DSN (DSN cấp thấp).
Dim cn As ADODB.Connection
Set cn = New ADODB.Connection
cn.Provider = "MSDASQL"
cn.ConnectionString = "DSN=Baigiang"
cn.Open
Kết nối DSN cấp thấp:
Dim cn As ADODB.Connection
Set cn = New ADODB.Connection
cn.Provider = "MSDASQL"
cn.ConnectionString = "DRIVER={SQL Server};” & _
“DATABASE=Baigiang;UID=myuser;PWD=mypassword;"
cn.Open
Trong trường hợp này việc kết nối với cơ sở dữ liệu Server được thực hiện nhanh hơn vì chương trình không cần đọc thông tin về các DSN trên máy Client, tuy nhiên thông tin về nguồn cơ sở dữ liệu lại kết chặt với chương trình đã biên dịch.
Để kết nối với cơ sở dữ liệu Access, ta dùng trình cung cấp Jet với chuỗi kết nối là đường dẫn đến tập tin .mdb
Dim cn As ADODB.Connection
Set cn = New ADODB.Connection
cn.Provider = "MicroSoft.Jet.OLEDB.4.0"
cn.ConnectionString = "d:\data\baigiang.mdb"
cn.Open
Đối với cơ sở dữ liệu SQL Server, ta có thể dùng trình cung cấp SQLOLEDB.1, trong trường hợp này, chuỗi kết nối tương tự như trường hợp kết nối dùng trình cung cấp ODBC không có DSN, tuy nhiên ta không cần xác định giá trị của DRIVER:
Dim cn as ADODB.Connection
Set cn = New ADODB.Connection
cn.Provider = “SQLOLEDB.1”
cn.ConnectionString = “DATABASE=DBHH;” & _
“SERVER=www;UID=user;PWD=user”
cn.Open
Mở và đóng nối kết nguồn dữ liệu
Để phát các yêu cầu đến nguồn dữ liệu sử dụng ADO, ta cần mở kết nối đến nguồn dữ liệu đó bằng phương thức Open của đối tượng Connection. Cú pháp đầy đủ như sau:
connection.Open [connect], [userid], [password]
Tất cả các tham số của phương thức Open đều là tùy chọn, nếu như các thông số này đã được xác định thông qua các thuộc tính khác của đối tượng Connection thì ta không cần mô tả chúng ở đây.
Khi đã hoàn thành tất cả các thao tác liên quan đến nối kết này, ta cần phải đóng nối kết một cách tường minh thông qua phương thức Close của đối tượng Connection.
connection.Close
Đóng nối kết một cách tường minh sẽ đảm bảo rằng tất cả các tài nguyên liên quan đến nối kết này trên Server cũng như Client đều được giải phóng một cách hợp lý.
Xác định vị trí con trỏ
Con trỏ (Cursor): một tập các mẩu tin được trả về cho chương trình. Vị trí con trỏ được xác định nhờ thuộc tính CursorLocation (có ở cả đối tượng Recordset). Có 2 giá trị có thể chỉ định:
- adUseClient: con trỏ phía Client.
- adUseServer: con trỏ phía Server (mặc định).
Thực thi các câu truy vấn hành động
Các câu truy vấn hành động (Insert, Update, Delete) được thực hiện nhờ phương thức Execute của đối tượng Connection; ngoài ra phương thức này cũng có thể được sử dụng để thực thi các thủ tục lưu trữ sẵn trong cơ sở dữ liệu hay các câu SELECT. Cú pháp phương thức này như sau:
Nếu không có kết quả trả về:
connection.Execute CommandText, RecordsAffected, Options
Có kết quả trả về:
Set recordset = connection.Execute (CommandText, RecordsAffected, Options)
Trong đó:
- connection: Đối tượng Connection.
- recordset: Đối tượng Recordset là kết quả trả về của phương thức Execute, tuy nhiên, người ta thường ít khi sử dụng cách này. Thay vào đó, người ta thường sử dụng phương thức Open của đối tượng Recordset.
- CommandText: là một chuỗi xác định câu truy vấn hành động, SELECT, thủ tục lưu trữ sẵn hay tên một bảng trong cơ sở dữ liệu.
- RecordEffected: Tùy chọn, là một số nguyên dài (Long) xác định trình cung cấp trả về bao nhiêu mẩu tin thỏa điều kiện.
- Options: Tùy chọn, là một số nguyên dài (Long) xác định trình cung cấp sẽ đánh giá các đối số của CommandText như thế nào.
Thuộc tính Mode: Xác định trình cung cấp có thể hạn chế truy cập đến cơ sở dữ liệu khi có một recordset đang mở. Các giá trị có thể là:
| Hằng số | Giá trị | Ý nghĩa |
| adModeUnknown | 0 | Mặc định, chỉ định quyền hạn chưa thiết lập hay không thể xác định |
| adModeRead | 1 | Mở Recordset với quyền chỉ đọc |
| adModeWrite | 2 | Mở Recordset với quyền chỉ ghi |
| adModeReadWrite | 3 | Mở Recordset với quyền đọc/ghi |
| adModeShareDenyRead | 4 | Ngăn người khác mở kết nối với quyền chỉ đọc |
| adModeShareDenyWrite | 8 | Ngăn người khác mở kết nối với quyền chỉ ghi |
| adModeShareExclusive | 12 | Ngăn người khác mở kết nối |
| adModeShareDenyNone | 16 | Ngăn người khác mở kết nối với bất cứ quyền nào |
Đối tượng Recordset
Để có thể khởi tạo một đối tượng Recordset ta có thể thực hiện một trong hai cách:
- Phương thức Execute của đối tượng Connection. Tuy nhiên cách này ta chỉ tạo được các Recordset chỉ đọc và chỉ có thể di chuyển tới.
- Xác lập các thông số thích hợp cho đối tượng Recordset rồi thực thi phuơng thức Open của đối tượng Recordset. Điều này được thực hiện nhờ các bước:
- Sau khi khởi tạo đối tượng Connection, chỉ định Recordset là của đối tượng Connection trên.
- Thiết lập các thuộc tính thích hợp của Recordset (Source, LockType…).
- Thực thi câu truy vấn nối kết nhờ phương thức Open.
Thuộc tính CursorType (loại con trỏ)
Xác định loại con trỏ được trả về từ cơ sở dữ liệu. Các giá trị có thể nhận:
| Hằng | Giá trị | Mô tả |
| adOpenForwardOnly | 0 | Chỉ có thể di chuyển phía trước |
| adOpenKeyset | 1 | Không thể thấy các mẩu tin do người dùng khác thêm vào nhưng khi họ xóa hay sửa đổi mẩu tin sẽ làm ảnh hưởng đến các mẩu tin ta đang làm việc. |
| adOpenDynamic | 2 | Có thể thấy toàn bộ sự thay đổi do người dùng khác tác động. |
| adOpenStatic | 3 | Bản sao tĩnh của tập mẩu tin. Mọi sự thay đổi của người dùng khác ta không thấy được |
Thuộc tính LockType (khóa mẩu tin)
Xác định cách thức khóa mẩu tin trong Recordset. Dùng tính năng này khi muốn kiểm soát cách thức cập nhật mẩu tin với nhiều người dùng trong cơ sở dữ liệu.
| Hằng | Giá trị | Mô tả |
| adLockReadOnly | 1 | Mặc định - Chỉ đọc. |
| adLockPessimistic | 2 | Khóa trang bi quan. Mẩu tin trong RecordSet bị khóa khi bắt đầu sửa đổi & tiếp tục khóa cho đến khi thi hành phương thức Update hay di chuyển sang mẩu tin khác. |
| adLockOptimistic | 3 | Khóa trang lạc quan. Mẩu tin chỉ bị khóa ngay lúc thi hành phương thức Update hay di chuyển sang mẩu tin khác. |
| adLockBatchOptimistic | 4 | Khóa trang lạc quan hàng loạt. Hỗ trợ cập nhật nhiều mẩu tin cùng một lúc. |
Thuộc tính Source
Đây là một chuỗi xác định câu truy vấn để lấy dữ liệu, có thể là tên của bảng hay tên của thủ tục lưu trữ sẵn.
Thuộc tính ActiveConnection
Đây là một thuộc tính đối tượng xác định Recordset là của nối kết nào trong chương trình.
Ví dụ sử dụng đối tượng Recordset trong chương trình
Đối tượng Recordset có thể được sử dụng là đối tượng nguồn dữ liệu (DataSource) của điều khiển lưới: Microsoft DataGrid Control 6.0 (OLEDB). Nhờ điều khiển lưới này ta có thể hiển thị dữ liệu từ một Recordset theo dạng hàng và cột.
Chẳng hạn ta có thể hiển thị trên lưới thông tin về các mặt hàng cùng với mã loại hàng của nó:
Dim cn As ADODB.Connection
Dim rs As ADODB.Recordset
Private Sub Form_Load()
Set cn = New ADODB.Connection
cn.Provider = "Microsoft.Jet.OLEDB.3.51"
cn.ConnectionString = "F:\Data\DBHH.mdb"
cn.Open
Set rs = New ADODB.Recordset
rs.Source = "SELECT MaHang, TenHang, DVTinh” & _
“TenLoai FROM THangHoa, TLoaiHang WHERE “ & _
“THangHoa.MaLoai = TLoaiHang.MaLoai"
Set rs.ActiveConnection = cn
rs.CursorLocation = adUseClient
rs.Open
Set grdHH.DataSource = rs
End Sub
Kết quả thực thi của chương trình này như sau:
*: Microsoft DataGrid Control 6.0 (OLEDB): Name: grdHH.
Cập nhật và thêm mới mẩu tin
Thêm mới mẩu tin
-Mở Recordset
-Thi hành phương thức AddNew
-Gán giá trị cho các trường trong mẩu tin của Recordset
-Lưu lại mẩu tin bằng cách thi hành phương thức Update (hay UpdateBatch).
Cập nhật mẩu tin
-Mở Recordset
-Thực hiện câu lệnh truy vấn để nhận về các mẩu tin thích hợp.
-Di chuyển đến mẩu tin cần cập nhật lại giá trị.
-Gán lại giá trị cho các trường.
- Thi hành phương thức Update (hay UpdateBatch tùy thuộc vào LockType).
Lưu ý:Chế độ khóa mẩu tin mặc định trong ADO là chỉ đọc, vì vậy ta phải đổi thuộc tính LockType của đối tượng Recordset sang chế độ soạn thảo trước khi thi hành cập nhật hay thêm mới mẩu tin.
Thuộc tính CursorLocation
Xác định tập mẩu tin trả về từ cơ sở dữ liệu được lưu ở đâu (Server hay Client, Server là mặc định). Thuộc tính cũng giống thuộc tính CursorLocation của đối tượng Connection.
Recordset ngắt kết nối
Khi chúng ta dùng con trỏ phía Client, ta có khả năng ngắt kết nối với Server cơ sở dữ liệu mà vẫn tiếp tục làm việc với dữ liệu. Cách này cho phép ứng dụng trở nên linh hoạt hơn bởi vì nhiều người dùng có thể làm việc với cùng một dữ liệu tại một thời điểm nếu như họ không có nối kết với server.
Để ngắt nối kết với Server, ta quy định thuộc tính ActiveConnection của đối tượng Recordset là Nothing.
Ví dụ:
Dim cn As ADODB.Connection
Private Sub Form_Load()
Set cn = New ADODB.Connection
cn.Provider = "Microsoft.Jet.OLEDB.3.51"
cn.ConnectionString = "F:\Data\GiangDay.mdb"
cn.Open
End Sub
Public Function GetList (strState As String) _
As ADODB.Recordset
Dim rs As ADODB.Recordset
Set rs = New ADODB.Recordset
Set rs.ActiveConnection = cn
rs.CursorLocation = adUseClient
rs.LockType = adLockBatchOptimistic
rs.CursorType = adOpenKeyset
rs.Open strState
Set rs.ActiveConnection = Nothing
Set GetList = rs
Set rs = Nothing
End Function
Để thi hành cùng một hành động trên một mẩu tin, ta sửa đổi lại các thuộc tính của đối tượng Recordset.
rs.LockType = adLockBatchOptimistic
rs.CursorType = adOpenKeyset
Chúng ta thiết lập giá trị các thuộc tính lại như trên để xác nhận rằng Recordset có thể nối kết lại để cập nhật về sau.
Sau đó, ta sẽ thiết lập một hàm nhận Recordset ngắt kết nối làm tham biến để tạo một đối tượng Recordset khác cập nhật dữ liệu.
Public Sub WriteData(rsDis As ADODB.Recordset)
Dim rs As ADODB.Recordset
Set rs = New ADODB.Recordset
Set rs.ActiveConnection = cn
rs.Open rsDis, cn
rs.UpdateBatch
End Sub
Gọi thực thi thủ tục WriteData:
Private Sub cmdWrite_Click()
WriteData GetList("Select * From THanghoa")
End Sub
Đối tượng Command
Đây là đối tượng được người lập trình sử dụng khi muốn thi hành các thủ tục lưu trữ sẵn hay những câu truy vấn có tham số.
Với đối tượng Command ta có thể thi hành một số công việc như sau:
- Sử dụng thuộc tính CommandText để định nghĩa các đoạn Text thi hành được. Thông thường thuộc tính này dùng để thiết lập một câu lệnh SQL hoặc một lời gọi thủ tục lưu trữ sẵn, hay những dạng khác mà trình cung cấp hỗ trợ
- Xây dựng chuỗi các đối số của câu truy vấn cũng như các tham số của các thủ tục lưu trữ sẵn thông qua đối tượng Parameter hoặc tập hợp Parameters.
- Thực hiện một câu truy vấn và trả về đối tượng Recordset thông qua phương thức Execute.
- Xác định kiểu của đối tượng Command để nâng cao hiệu quả thông qua thuộc tính CommandType.
- Xác định số giây mà trình cung cấp phải chờ khi thi hành một đối tượng Command thông qua thuộc tính CommandTimeOut.
Các kiểu của đối tượng Command được trình bày trong bảng dưới đây:
| Hằng | Ý nghĩa |
| adCmdText | Định giá thuộc tính CommandText dưới dạng Text của một câu lệnh hoặc một lời gọi thủ tục lưu trữ sẵn. |
| adCmdTable | Định giá thuộc tính CommandText như là tên của một bảng khi tất cả các trường của bảng đó sẽ được trả về bởi câu lệnh truy vấn nội tại. |
| adCmdTableDirect | Định giá thuộc tính CommandText như là tên của một bảng khi mà tất cả các trường của bảng đó sẽ được trả về. |
| adCmdStoredProc | Định giá thuộc tính CommandText như là tên của một thủ tục lưu trữ sẵn. |
| adExecuteNoRecords | Chỉ định rằng thuộc tính CommandText là một câu lệnh hoặc một thủ tục lưu trữ sẵn không trả về bất kỳ dòng nào (ví dụ như lệnh thêm mới dữ liệu …). Cấu trúc này luôn bao hàm adCmdText, adCmdStoredProc. |
Thuộc tính Parameter được xác lập thông qua hai phương thức CreateParameter và Append
Set parameter = command.CreateParameter (Name, Type, _
Direction, Size, Value)
- Name: tùy chọn, chuỗi xác định tên của đối tượng Parameter.
- Type, Direction: giá trị xác địn kiểu của đối tượng Parameter
- Size: giá trị xác định độ dài tối đa của giá trị đối tượng Parameter bằng ký tự hoặc Byte.
- Value: biến xác định giá trị của Parameter truyền.
Những giá trị có thể của thuộc tính Direction:
| Hằng | Mô tả |
| adParamUnknown | Không biết chiều của Parameter. |
| adParamInput | Mặc định, xác định đây là tham số đầu vào. |
| adParamOutput | Tham số đầu ra. |
| adParamInputOutput | Vừa là tham số đầu vào vừa là tham số đầu ra. |
| adParamReturnValue | Đây là giá trị trả về. |
Phương thức Append dùng để đưa đối tượng Parameter vừa tạo vào tập hợp. Chúng ta sẽ xét qua ví dụ dau đây:
Public Sub ActiveConnectionX()
Dim cnn1 As ADODB.Connection
Dim cmdByRoyalty As ADODB.Command
Dim prmByRoyalty As ADODB.Parameter
Dim rstByRoyalty As ADODB.Recordset
Dim rstAuthors As ADODB.Recordset
Dim intRoyalty As Integer
Dim strAuthorID As String
Dim strCnn As String
' Định nghĩa 1 đối tượng command cho một thủ tục lưu trữ sẵn
Set cnn1 = New ADODB.Connection
cnn1.Provider = "SQLOLEDB.1"
cnn1.ConnectionString = "DATABASE=Pubs;" & _
"SERVER=(local);UID=user;PWD=user;"
cnn1.Open
Set cmdByRoyalty = New ADODB.Command
Set cmdByRoyalty.ActiveConnection = cnn1
cmdByRoyalty.CommandText = "byroyalty"
cmdByRoyalty.CommandType = adCmdStoredProc
cmdByRoyalty.CommandTimeout = 15
' Định nghĩa đối số đầu vào cho thủ tục lưu trữ
intRoyalty = Trim(InputBox( "Enter royalty:"))
Set prmByRoyalty = New ADODB.Parameter
prmByRoyalty.Type = adInteger
prmByRoyalty.Size = 3
prmByRoyalty.Direction = adParamInput
prmByRoyalty.Value = intRoyalty
cmdByRoyalty.Parameters.Append prmByRoyalty
' Tạo một recordset bằng cách thi hành đối tượng Command.
Set rstByRoyalty = cmdByRoyalty.Execute()
' Mở bảng Authors để lấy tên hiển thị
Set rstAuthors = New ADODB.Recordset
rstAuthors.Open "authors", cnn1, , , adCmdTable
Debug.Print "Authors with " & intRoyalty & _
" percent royalty"
Do While Not rstByRoyalty.EOF
strAuthorID = rstByRoyalty!au_id
Debug.Print , rstByRoyalty!au_id & ", ";
rstAuthors.Filter = "au_id = '" & _
strAuthorID & "'"
Debug.Print rstAuthors!au_fname & “ - “ & _
rstAuthors!au_lname
rstByRoyalty.MoveNext
Loop
rstByRoyalty.Close
rstAuthors.Close
cnn1.Close
End Sub
Đối tượng Field
Dùng đối tượng Field và tập hợp Fields khi ta muốn truy cập giá trị của một trường của một Recordset nào đó, kỹ thuật này tương tự như đối với DAO.
Dịch vụ dữ liệu từ xa của ADO
Đây là kỹ thuật sử dụng thư viện Remote Data Service (RDS) để vận chuyển ADO Recordset từ server đến máy tính client Recordset kết quả được lưu ở máy client và chúng được ngắt kết nối đến server.
RDS là một phần của Microsoft Data Access Components (MDAC). Các thông tin về RDS có thể tìm thấy ở trang http://www.microsoft.com/data/. RDS gồm 2 phần chính:
- RDS 1.5 server: đi kèm khi cài đặt Internet Information Server (IIS) 4.0.
- RDS 1.5 client đi kèm khi cài đặt Internet Explorer (IE) 4.0.
Thư viện ADODB gồm các thành phần hoạt động chủ yếu phía server (server side) như các đối tượng Connection, Command, Error, Parameters ... Sẽ thật hiệu quả nếu sử dụng các thành phần này giao tiếp với cơ sở dữ liệu. Tuy nhiên trong trường hợp sử dụng các chức năng cần phải có ở phía client thì ta cần phải phân phối kèm theo một số tập tin và sử dụng ODBC cho mỗi máy client. Đối tượng ADODB Recordset không thể phân phối với các thành phần của RDS Client. Thay vào đó thư viện đối tượng Microsoft ActiveX Data Objects RecordSet (ADOR) được sử dụng. Thư viện này gồm các thành phần hoàn toàn nằm ở phía client và cho phép ta có các thao tác trên một recordset thật sự phía client. ADOR không có các đối tượng Connection, Command, Error, hay Parameters. ADOR có các chức năng cho phép phân phối recordset với các thành phần RDS client.
Một ADO Recordset không thể vận chuyển thông qua giao thức http. Thay vào đó RDS được sử dụng để nhận và tương tác dữ liệu từ xa thông qua http. Một proxy RDS được sử dụng để kiểm soát từ xa một ADOR Recordset ngắt kết nối truyền thông qua giao thức http. Như vậy RDS là vật chứa (container) cho phép lưu trữ và truy cập từ xa các ADOR Recordset.
Ta có thể dùng đối tượng DataControl của RDS để nhận về đối tượng Recordset của ADO từ Internet.
Để có thể sử dụng kỹ thuật này, ta cần tham khảo các thuộc tính chủ yếu của đối tượng DataControl.
- Thuộc tính Connect:
DataControl.Connect = "DSN=DSNName;UID=usr;PWD=pw;"
- Thuộc tính Server: Xác định máy chủ Web chứa nguồn dữ liệu bao gồm tên và giao thức nối kết.
- Thuộc tính SQL: Là câu lệnh truy vấn để nhận về đối tượng Recordset
DataControl.SQL = "QueryString"
- Thuộc tính ExecuteOptions: xác định việc thi hành các câu lệnh truy vấn một cách đồng bộ hay không, các giá trị là một trong hai giá trị sau đây:
| Hằng | Mô tả |
| adcExecSync | Thi hành đồng bộ |
| adcExecAsync | Mặc định, Thi hành không đồng bộ. |
- Thuộc tính ReadyState: Xác định trạng thái của điều khiển.
| Giá trị | Mô tả |
| adcReadyStateLoaded | Câu truy vấn hiện hành vẫn đang còn thực hiện và chưa có một dòng nào được trả về. Đối tượng Recordset của RDS.DataControl chưa thể sử dụng. |
| adcReadyStateInteractive | Tập hợp dòng ban đầu đã được trả về và chứa trong đối tượng Recordset, các dòng tiếp theo vẫn đang được trả về. |
| adcReadyStateComplete | Tất cả các dòng đều đã được chứa trong đối tượng Recordset. |
- Phương thức Refresh: thi hành câu truy vấn.
- Thuộc tính Recordset: trả về Recordset kết quả.
Recordset = DataControl.Recordset
- Phương thức DoEvents: Đây là hàm của VB, nó sẽ trả điều khiển cho hệ điều hành thực hiện các quá trình khác.
